path: root/nix/flake/hosts.nix

{ inputs, self, ... }:
let
  inherit (inputs) nixpkgs darwin home-manager firefox-darwin nur;
  inherit (nixpkgs.lib) mkMerge;

  mkDarwinConfig = system: path:
    darwin.lib.darwinSystem {
      inherit system;
      modules = [
        home-manager.darwinModules.home-manager
        {
          home-manager = {
            useGlobalPkgs = true;
            useUserPackages = true;
            extraSpecialArgs = {
              inherit self;
            };
          };
        }
        ../../hosts/common/darwin/homebrew.nix
        ../../hosts/common/darwin/macos.nix
        path
        {
          nixpkgs.overlays = [
            firefox-darwin.overlay
            nur.overlay
          ];
        }
      ];
      specialArgs = { inherit inputs self; };
    };
in
{
  flake = mkMerge [
    {
      darwinConfigurations = {
        mba-fcuny = mkDarwinConfig "aarch64-darwin" ../../hosts/mba;
        HQ-C02FK3Q7MD6T = mkDarwinConfig "x86_64-darwin" ../../hosts/work;
      };
    }
  ];
}