From 23f8df7396d35744069a4bda0d1d38a55ff64b79 Mon Sep 17 00:00:00 2001
From: Franck Cuny <franck@fcuny.net>
Date: Mon, 21 Jul 2025 07:31:45 -0700
Subject: refactoring to use flake-parts and automatic imports of hosts

This is the first step in a large refactoring to use flake-parts, and to
automatically imports hosts based on paths.
---
 nix/flake/devshells.nix | 57 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 nix/flake/devshells.nix

(limited to 'nix/flake/devshells.nix')

diff --git a/nix/flake/devshells.nix b/nix/flake/devshells.nix
new file mode 100644
index 0000000..339a8f4
--- /dev/null
+++ b/nix/flake/devshells.nix
@@ -0,0 +1,57 @@
+{ inputs, ... }:
+{
+  perSystem =
+    { system, pkgs, ... }:
+    let
+      treefmtEval = inputs.treefmt-nix.lib.evalModule pkgs {
+        projectRootFile = "flake.nix";
+        programs = {
+          nixfmt.enable = true;
+          deadnix.enable = true;
+        };
+      };
+
+      mkPreCommitHooks =
+        src:
+        inputs.pre-commit-hooks.lib.${system}.run {
+          inherit src;
+          hooks = {
+            check-merge-conflicts.enable = true;
+            deadnix.enable = true;
+            detect-private-keys.enable = true;
+            end-of-file-fixer.enable = true;
+            mixed-line-endings.enable = true;
+            shellcheck = {
+              enable = true;
+              excludes = [ "\\.envrc$" ];
+            };
+            flake-checker.enable = true;
+            treefmt = {
+              enable = true;
+              entry = "${treefmtEval.config.build.wrapper}/bin/treefmt --ci";
+            };
+            trim-trailing-whitespace.enable = true;
+          };
+        };
+
+      pre-commit-check = mkPreCommitHooks ./.;
+      scripts = import ../../nix/scripts {
+        inherit pkgs system inputs;
+      };
+    in
+    {
+      devShells = {
+        default = pkgs.mkShellNoCC {
+          inherit (pre-commit-check) shellHook;
+          packages =
+            with pkgs;
+            [
+              nixos-rebuild
+              git
+              inputs.agenix.packages."${system}".default
+            ]
+            ++ scripts.all;
+        };
+      };
+    };
+}
-- 
cgit v1.2.3