From 52ac07299f2342afe0c309f3b8be3ea05c7549ff Mon Sep 17 00:00:00 2001
From: Franck Cuny <franck@fcuny.net>
Date: Sun, 8 Dec 2024 13:58:02 -0800
Subject: refactor overall configuration

The configuration of the various hosts and home-manager was becoming a
bit complex for no valid reasons. Try to simplify this a bit.
---
 nix/lib/mkSystem.nix | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 nix/lib/mkSystem.nix

(limited to 'nix/lib/mkSystem.nix')

diff --git a/nix/lib/mkSystem.nix b/nix/lib/mkSystem.nix
new file mode 100644
index 0000000..dbacac6
--- /dev/null
+++ b/nix/lib/mkSystem.nix
@@ -0,0 +1,50 @@
+# This function creates a NixOS system based on our VM setup for a
+# particular architecture.
+{ nixpkgs, inputs }:
+
+name:
+{ system, user, darwin ? false, }:
+
+let
+  # The config files for this system.
+  machineConfig = ../machines/${name}.nix;
+  userOSConfig = ../users/${user}/${if darwin then "darwin" else "nixos"}.nix;
+  userHMConfig = ../users/${user}/home-manager.nix;
+
+  # NixOS vs nix-darwin functionst
+  systemFunc =
+    if darwin then inputs.darwin.lib.darwinSystem else nixpkgs.lib.nixosSystem;
+  home-manager =
+    if darwin then
+      inputs.home-manager.darwinModules
+    else
+      inputs.home-manager.nixosModules;
+in
+systemFunc rec {
+  inherit system;
+
+  modules = [
+    # Allow unfree packages.
+    { nixpkgs.config.allowUnfree = true; }
+
+    machineConfig
+    userOSConfig
+    home-manager.home-manager
+    {
+      home-manager.useGlobalPkgs = true;
+      home-manager.useUserPackages = true;
+      home-manager.users.${user} = import userHMConfig { inputs = inputs; };
+    }
+
+    # We expose some extra arguments so that our modules can parameterize
+    # better based on these values.
+    {
+      config._module.args = {
+        currentSystem = system;
+        currentSystemName = name;
+        currentSystemUser = user;
+        inputs = inputs;
+      };
+    }
+  ];
+}
-- 
cgit v1.2.3