From 8093f1bc8a54c4f205460d4fbc1706f45bb6a195 Mon Sep 17 00:00:00 2001
From: franck cuny <franck@lumberjaph.net>
Date: Wed, 16 Jun 2010 13:32:54 +0200
Subject: accept multiples hosts so we don't always hit the same node

---
 lib/Net/Riak/Role/Hosts.pm | 44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 lib/Net/Riak/Role/Hosts.pm

(limited to 'lib/Net/Riak/Role/Hosts.pm')

diff --git a/lib/Net/Riak/Role/Hosts.pm b/lib/Net/Riak/Role/Hosts.pm
new file mode 100644
index 0000000..5171928
--- /dev/null
+++ b/lib/Net/Riak/Role/Hosts.pm
@@ -0,0 +1,44 @@
+package Net::Riak::Role::Hosts;
+
+use Moose::Role;
+use Moose::Util::TypeConstraints;
+
+subtype 'RiakHost' => as 'ArrayRef[HashRef]';
+
+coerce 'RiakHost' => from 'Str' => via {
+    [{node => $_, weight => 1}];
+};
+coerce 'RiakHost' => from 'ArrayRef' => via {
+    my $backends = $_;
+    my $weight   = 1 / @$backends;
+    [map { {node => $_, weight => $weight} } @$backends];
+};
+coerce 'RiakHost' => from 'HashRef' => via {
+    my $backends = $_;
+    my $total    = 0;
+    $total += $_ for values %$backends;
+    [map { {node => $_, weight => $backends->{$_} / $total} }
+          keys %$backends];
+};
+
+has host => (
+    is      => 'rw',
+    isa     => 'RiakHost',
+    coerce  => 1,
+    default => sub {'http://127.0.0.1:8098'}
+);
+
+sub get_host {
+    my $self = shift;
+
+    my $choice;
+    my $rand = rand;
+
+    for (@{$self->host}) {
+        $choice = $_->{node};
+        ($rand -= $_->{weight}) <= 0 and last;
+    }
+    $choice;
+}
+
+1;
-- 
cgit v1.2.3