path: root/flake/overlays.nix

{
  inputs,
  self,
  config,
  ...
}:
{

  flake.overlays.default = _final: prev: {
    sapi = prev.callPackage "${self}/pkgs/sapi" { };
    hashi = prev.callPackage "${self}/pkgs/hashi" { };
  };

  perSystem =
    { system, ... }:
    let
      mkTerraformCfg =
        modules:
        inputs.terranix.lib.terranixConfiguration {
          inherit system;
          extraArgs = {
            inherit (config.flake) nixosConfigurations;
          };
          inherit modules;
        };
    in
    {
      _module.args.pkgs = import inputs.nixpkgs {
        inherit system;
        config.allowUnfree = true;
        overlays = [
          inputs.agenix.overlays.default
          inputs.emacs-overlay.overlay
          inputs.nur.overlays.default
          inputs.my-go-tools.overlays.default
          self.overlays.default
          (_self: _super: {
            adminTerraformCfg = mkTerraformCfg [
              "${self}/terraform/admin"
            ];
          })
        ];
      };
    };
}