path: root/nix/users/fcuny/emacs.nix

{ pkgs, lib, ... }:
let
  packages =
    epkgs: with epkgs; [
      aidermacs # pair programming in Emacs with Aider
      cape
      consult
      corfu
      diminish
      direnv
      docker
      docker-compose-mode
      dockerfile-mode
      exec-path-from-shell
      git-link
      go-mode
      gotest
      gptel # LLM client for Emacs
      hcl-mode
      jq-mode
      json-mode
      json-reformat
      magit
      marginalia
      nix-mode
      orderless
      protobuf-mode
      rg
      terraform-mode
      toml-mode
      tree-sitter
      tree-sitter-langs
      treesit-grammars.with-all-grammars
      vertico
      yaml-mode
      yasnippet
      yasnippet-capf
    ];
  emacsFiles = [
    "early-init.el"
    "init.el"
    "site-lisp/init-base.el"
    "site-lisp/init-completion.el"
    "site-lisp/init-llm.el"
    "site-lisp/init-programming.el"
    "site-lisp/init-ui.el"
  ];
  mkEmacsFile = file: {
    ".config/emacs/${file}" = {
      source = ./configs/emacs/${file};
    };
  };
in
{
  home.file = lib.mkMerge (map mkEmacsFile emacsFiles);

  programs.emacs = {
    enable = true;
    extraPackages = packages;
    package = pkgs.emacs.override { withNativeCompilation = false; };
  };

  home.packages = with pkgs; [
    aspell
    aspellDicts.en
    aspellDicts.en-science
    aspellDicts.en-computers
  ];

  home.sessionVariables = {
    EDITOR = "${pkgs.emacs}/bin/emacsclient -a=";
  };
}