path: root/users/fcuny/desktop/trust/email.nix

{ pkgs, config, lib, ... }:

{
  accounts.email = {
    maildirBasePath = "${config.home.homeDirectory}/.mail";
    accounts = {
      Fastmail = rec {
        primary = true;
        address = "franck@fcuny.net";
        userName = address;
        realName = "Franck Cuny";
        aliases =  [ "franck.cuny@gmail.com" ];
        passwordCommand = "pass email/imap.fastmail.com";
        imap.host = "imap.fastmail.com";
        mbsync = {
          enable = true;
          create = "maildir";
          expunge = "both";
        };
        notmuch.enable = true;
      };
    };
  };

  programs.mbsync.enable = true;

  programs.notmuch = {
    enable = true;
    maildir.synchronizeFlags = true;
    new.tags = [ "unread" "inbox" ];
    new.ignore = [ "Trash" ];
    search.excludeTags = [ "spam" "deleted" ];
  };

  xdg.configFile."notmuch/imap-sync.sh" = {
    executable = true;
    text = ''
      #!${pkgs.stdenv.shell}
      MAILDIR=$HOME/.mail/

      # Strip UIDs from filenames when moving mails so that mbsync doesn't get confused.
      mv_renamed() {
        while IFS= read -r name; do
          flags=$(echo "$name" | cut -d':' -f2)
          new_name="$(basename $name | awk -F ',' '{print $1}')"
          [ -f "$name" ] && mv -nv "$name" "$1/$new_name"
        done
      }

      ${pkgs.notmuch}/bin/notmuch search --output=files -- not tag:inbox and folder:Fastmail/Inbox | mv_renamed $MAILDIR/Fastmail/Archive/cur
  '';
  };

  systemd.user.services.mbsync = {
    Unit = {
      Description = "mbsync synchronization";
    };
    Service = {
      Type = "oneshot";
      Environment = [
       "PASSWORD_STORE_DIR=${config.programs.password-store.settings.PASSWORD_STORE_DIR}"
        "NOTMUCH_CONFIG=${config.xdg.configHome}/notmuch/notmuchrc"
      ];
      ExecStartPre = "${config.xdg.configHome}/notmuch/imap-sync.sh";
      ExecStart = "${pkgs.isync}/bin/mbsync -a";
      ExecStartPost = "${pkgs.notmuch}/bin/notmuch new --quiet";
    };
  };

  systemd.user.timers.mbsync = {
    Unit = { Description = "mbsync synchronization"; };
    Timer = {
      OnBootSec = "30";
      OnUnitActiveSec = "5m";
    };
    Install = { WantedBy = [ "timers.target" ]; };
  };
}