flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110

{
  description = "personal NixOS configurations";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-24.11";

    home-manager = {
      url = "github:nix-community/home-manager/release-24.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    darwin = {
      url = "github:lnl7/nix-darwin/nix-darwin-24.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    pre-commit-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  # Output config, or config for NixOS system
  outputs =
    {
      nixpkgs,
      darwin,
      treefmt-nix,
      pre-commit-hooks,
      ...
    }@inputs:
    let
      system = "aarch64-darwin";
      pkgs = import nixpkgs { inherit system; };
      mkSystem = import ./nix/lib/mkSystem.nix { inherit nixpkgs inputs; };
      treefmtEval = treefmt-nix.lib.evalModule pkgs {
        projectRootFile = "flake.nix";
        programs = {
          nixfmt.enable = true;
          actionlint.enable = true;
          deadnix.enable = true;
        };
      };
    in
    {
      # nix fmt
      formatter.${system} = treefmtEval.config.build.wrapper;

      # nix flake check
      checks.${system} = {
        pre-commit-check = inputs.pre-commit-hooks.lib.${pkgs.system}.run {
          src = ./.;
          hooks = {
            actionlint.enable = true;
            check-merge-conflicts.enable = true;
            deadnix.enable = true;
            detect-private-keys.enable = true;
            end-of-file-fixer.enable = true;
            mixed-line-endings.enable = true;
            shellcheck.enable = true;
            treefmt = {
              enable = true;
              entry = "${treefmtEval.config.build.wrapper}/bin/treefmt --ci";
            };
            trim-trailing-whitespace.enable = true;
          };
        };
      };

      # my personal MacBook Air
      darwinConfigurations.mba-m2 = mkSystem "mba-m2" {
        system = "aarch64-darwin";
        user = "fcuny";
        darwin = true;
      };

      # work laptop
      darwinConfigurations.hq-kwny2vh41p = mkSystem "hq-kwny2vh41p" {
        system = "aarch64-darwin";
        user = "fcuny";
        darwin = true;
      };

      devShells.${system}.default = pkgs.mkShellNoCC {
        packages = with pkgs; [
          git
          (writeScriptBin "nbuild" ''
            set -e
            echo "> Running darwin-rebuild switch..."
            ${inputs.darwin.packages.${system}.darwin-rebuild}/bin/darwin-rebuild build --flake .
            echo "> darwin-rebuild build was successful ✅"
            echo "> macOS config was successfully applied 🚀"
          '')
          (writeScriptBin "nswitch" ''
            set -e
            echo "> Running darwin-rebuild switch..."
            ${inputs.darwin.packages.${system}.darwin-rebuild}/bin/darwin-rebuild switch --flake .
            echo "> darwin-rebuild build was successful ✅"
            echo "> macOS config was successfully applied 🚀"
          '')
          (writeScriptBin "update-deps" "nix flake update --commit-lock-file")
        ];
      };
    };
}