blob: d404578a833ca1ad82652637ec55e4c7cde6230d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
|
{
description = "personal NixOS configurations";
inputs = {
nixpkgs.url = "github:nixos/nixpkgs/nixos-24.11";
home-manager = {
url = "github:nix-community/home-manager/release-24.11";
inputs.nixpkgs.follows = "nixpkgs";
};
darwin = {
url = "github:lnl7/nix-darwin/nix-darwin-24.11";
inputs.nixpkgs.follows = "nixpkgs";
};
treefmt-nix = {
url = "github:numtide/treefmt-nix";
inputs.nixpkgs.follows = "nixpkgs";
};
flake-utils.url = "github:numtide/flake-utils";
pre-commit-hooks = {
url = "github:cachix/pre-commit-hooks.nix";
inputs.nixpkgs.follows = "nixpkgs";
};
devshell = {
url = "github:numtide/devshell";
inputs.nixpkgs.follows = "nixpkgs";
};
};
# Output config, or config for NixOS system
outputs =
{
self,
nixpkgs,
darwin,
flake-utils,
pre-commit-hooks,
devshell,
treefmt-nix,
...
}@inputs:
flake-utils.lib.eachDefaultSystem (
system:
let
pkgs = import nixpkgs {
inherit system;
overlays = [ devshell.overlays.default ];
};
treefmt = (
treefmt-nix.lib.mkWrapper pkgs {
projectRootFile = "flake.nix";
programs = {
nixfmt.enable = true;
actionlint.enable = true;
deadnix.enable = true;
just.enable = true;
};
}
);
in
{
checks = {
pre-commit-check = pre-commit-hooks.lib.${system}.run {
src = ./.;
hooks = {
check-merge-conflicts.enable = true;
end-of-file-fixer.enable = true;
treefmt-check = {
enable = true;
entry = "${treefmt}/bin/treefmt --fail-on-change";
pass_filenames = false;
};
};
};
};
formatter = treefmt;
devShells.default = pkgs.devshell.mkShell {
packages = with pkgs; [
just
treefmt
];
devshell.startup.pre-commit.text = self.checks.${system}.pre-commit-check.shellHook;
env = [
{
name = "DEVSHELL_NO_MOTD";
value = "1";
}
];
};
}
)
// (flake-utils.lib.eachDefaultSystemPassThrough (
system:
let
mkSystem = import ./nix/lib/mkSystem.nix { inherit nixpkgs inputs; };
in
{
# a VM running on the MacBook Air
nixosConfigurations.vm-aarch64 = mkSystem "vm-aarch64" {
system = "aarch64-linux";
user = "fcuny";
};
# a VM running on the synology DS923+
nixosConfigurations.vm-synology = mkSystem "vm-synology" {
system = "x86_64-linux";
user = "fcuny";
};
# my personal MacBook Air
darwinConfigurations.mba-m2 = mkSystem "mba-m2" {
system = "aarch64-darwin";
user = "fcuny";
darwin = true;
};
# work laptop
darwinConfigurations.hq-kwny2vh41p = mkSystem "hq-kwny2vh41p" {
system = "aarch64-darwin";
user = "fcuny";
darwin = true;
};
}
));
}
|
