flake/devshells.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

{ self, inputs, ... }:
{
  perSystem =
    { system, pkgs, ... }:
    let
      treefmtEval = inputs.treefmt-nix.lib.evalModule pkgs {
        projectRootFile = "flake.nix";
        programs = {
          nixfmt.enable = true;
          deadnix.enable = true;
          terraform.enable = true;
        };
      };

      mkPreCommitHooks =
        src:
        inputs.pre-commit-hooks.lib.${system}.run {
          inherit src;
          hooks = {
            check-merge-conflicts.enable = true;
            deadnix.enable = true;
            detect-private-keys.enable = true;
            end-of-file-fixer.enable = true;
            mixed-line-endings.enable = true;
            shellcheck = {
              enable = true;
              excludes = [ "\\.envrc$" ];
            };
            flake-checker.enable = true;
            treefmt = {
              enable = true;
              entry = "${treefmtEval.config.build.wrapper}/bin/treefmt --ci";
            };
            trim-trailing-whitespace.enable = true;
          };
        };

      pre-commit-check = mkPreCommitHooks ./.;
      scripts = import "${self}/scripts" {
        inherit
          pkgs
          system
          inputs
          ;
      };
    in
    {
      devShells = {
        default = pkgs.mkShellNoCC {
          inherit (pre-commit-check) shellHook;
          packages =
            with pkgs;
            [
              nixos-rebuild
              git
              inputs.agenix.packages."${system}".default
            ]
            ++ scripts.all;
        };
      };
    };
}