blob: 3ae840e668b0ea67ee355eb7e195865be711bd8d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
|
{
inputs,
self,
withSystem,
...
}:
let
inherit (inputs.nixpkgs.lib // builtins)
filterAttrs
foldl'
makeOverridable
mapAttrs'
mapAttrsToList
mkForce
mkIf
nixosSystem
readDir
substring
;
inherit (inputs.darwin.lib) darwinSystem;
nixSettings = {
nix.registry.nixpkgs = {
flake = inputs.nixpkgs;
};
};
mapSystems =
dir: mapAttrsToList (name: _: name) (filterAttrs (_: type: type == "directory") (readDir dir));
mapHosts = foldl' (
hosts: system:
hosts
// (mapAttrs' (name: _: {
inherit name;
value = {
inherit system;
hostconf = "${self}/machines/nixos/${system}/${name}";
};
}) (builtins.readDir "${self}/machines/nixos/${system}"))
) { };
mapMacs = foldl' (
hosts: system:
hosts
// (mapAttrs' (name: _: {
inherit name;
value = {
inherit system;
hostconf = "${self}/machines/darwin/${system}/${name}";
};
}) (builtins.readDir "${self}/machines/darwin/${system}"))
) { };
defaultModules = [
nixSettings
inputs.agenix.nixosModules.age
inputs.disko.nixosModules.disko
inputs.home-manager.nixosModules.home-manager
"${self}/modules/home.nix"
"${self}/modules/host-config.nix"
"${self}/modules/nas-client.nix"
"${self}/modules/backups.nix"
];
darwinDefaultModules = [
nixSettings
inputs.agenix.darwinModules.age
inputs.home-manager.darwinModules.home-manager
"${self}/modules/home.nix"
"${self}/modules/host-config.nix"
];
darwinConfigurations = mapAttrs' (
name: conf:
let
inherit (conf) system hostconf;
adminUser = {
name = "fcuny";
userinfo = {
email = "franck@fcuny.net";
fullName = "Franck Cuny";
};
};
in
{
inherit name;
value = withSystem system (
{ pkgs, ... }:
makeOverridable darwinSystem {
inherit system;
specialArgs = {
hostName = name;
inherit adminUser;
inherit self;
inherit inputs;
};
modules = [
{ inherit adminUser; }
{
nixpkgs.pkgs = pkgs;
nixpkgs.hostPlatform = system;
system.stateVersion = 5;
environment.systemPackages = [
pkgs.git
];
}
]
++ darwinDefaultModules
++ [
hostconf
];
}
);
}
) (mapMacs (mapSystems "${self}/machines/darwin"));
nixosConfigurations = mapAttrs' (
name: conf:
let
inherit (conf) system hostconf;
adminUser = {
name = "fcuny";
uid = 1000;
userinfo = {
email = "franck@fcuny.net";
fullName = "Franck Cuny";
};
};
in
{
inherit name;
value = withSystem system (
{ pkgs, ... }:
makeOverridable nixosSystem {
inherit system;
specialArgs = {
hostName = name;
inherit adminUser;
inherit self;
hostConfigurations = mapAttrs' (name: conf: {
inherit name;
value = conf.config;
}) nixosConfigurations;
inherit inputs;
};
modules = [
{ inherit adminUser; }
{
system.configurationRevision = mkIf (self ? rev) self.rev;
system.nixos.versionSuffix = mkForce "git.${substring 0 11 inputs.nixpkgs.rev}";
nixpkgs.pkgs = pkgs;
environment.systemPackages = [
pkgs.git
];
}
]
++ defaultModules
++ [
hostconf
inputs.my-go-tools.nixosModules.default
];
}
);
}
) (mapHosts (mapSystems "${self}/machines/nixos"));
in
{
flake = {
inherit nixosConfigurations darwinConfigurations;
};
}
|
